send e-mail

I have created a new class with a static method that I can easily call from any .update() method to alert me when a record changes, and what changed in the record.



static void CompareAndEmail(str emailTemplateName, str nameField, str recipient, Common original, Common modified)

{

    UserInfo    userInfo;

    Map         emailParameterMap = new Map(Types::String, Types::String);

    str         changes;

    int         i, fieldId;   

    DictTable   dictTable = new DictTable(original.TableId);

    DictField   dictField;

;



    for (i=1; i<=dictTable.fieldCnt(); i++)

    {

        fieldId = dictTable.fieldCnt2Id(i);

        dictField = dictTable.fieldObject(fieldId);



        if (dictField.isSystem())

            continue;



        if (original.(fieldId) != modified.(fieldId))

        {

            changes += strfmt("%1: %2 -> %3 \n\r",

                dictField.name(),

                original.(fieldId),

                modified.(fieldId)

            );

        }

    }



    //Send Notification Email

    select Name from UserInfo where userInfo.id == curUserId();

    emailParameterMap.insert("modifiedBy", userInfo.Name);

    emailParameterMap.insert("tableName", dictTable.name());

    emailParameterMap.insert("recordName", original.(dictTable.fieldName2Id(nameField)));

    emailParameterMap.insert("recordChanges", changes);



    SysEmailTable::sendMail(emailTemplateName, "en-us", recipient, emailParameterMap);

}



Then in the .update() method I just add this one line

//Compare and email differences
RecordChangeNotification::CompareAndEmail(
    "RecChange",            //Template to use
    "Name",                 //Name field of the record (MUST BE VALID)
    "user@domain.com", //Recipient email
    this_Orig,              //Original record
    this                    //Modified record
);

The only things I want to improve upon are:

• moving the template name and recipient into a table, for easier maintenance


• better formatting for the change list, I don't know how to template that

I have created an email template in Ax, using the %varname% as a placeholder for items added to the map when you send the email with this:

emailParameterMap.insert("modifiedBy", userFullName);
emailParameterMap.insert("vendorName", vendorName);

SysEmailTable::sendMail("VendChanges", "en-us", "user@domain.com", emailParameterMap);